Merged r9433:9527 from features/gr-usrp2 into trunk. Adds usrp2 and gr-usrp2 top-level components. Trunk passes distcheck with mb-gcc installed, but currently not without them. The key issue is that when mb-gcc is not installed, the build system skips over the usrp2/firmware directory, and the firmware include files don't get put into the dist tarball. But we can't do the usual DIST_SUBDIRS method as the firmware is a subpackage.

git-svn-id: http://gnuradio.org/svn/gnuradio/trunk@9528 221aa14e-8319-0410-a670-987f0aec2ac5

1 files changed, 56 insertions, 0 deletions

diff --git a/control_lib/cascadefifo2.v b/control_lib/cascadefifo2.v
new file mode 100644
index 000000000..984cc46e6
--- /dev/null
+++ b/control_lib/cascadefifo2.v
@@ -0,0 +1,56 @@
+
+
+// This FIFO exists to provide an intermediate point for the data on its
+// long trek from one RAM (in the buffer pool) to another (in the longfifo)
+// The shortfifo is more flexible in its placement since it is based on
+// distributed RAM
+
+// This one has the shortfifo on both the in and out sides.
+module cascadefifo2
+  #(parameter WIDTH=32, SIZE=9)
+    (input clk, input rst,
+     input [WIDTH-1:0] datain,
+     output [WIDTH-1:0] dataout,
+     input read,
+     input write,
+     input clear,
+     output full,
+     output empty,
+     output [15:0] space,
+     output [15:0] occupied);
+
+   wire [WIDTH-1:0] data_int, data_int2;
+   wire 	    empty_int, full_int, transfer;
+   wire 	    empty_int2, full_int2, transfer2;
+   wire [4:0] 	    s1_space, s1_occupied, s2_space, s2_occupied;
+   wire [15:0] 	    l_space, l_occupied;
+   
+   shortfifo #(.WIDTH(WIDTH)) shortfifo
+     (.clk(clk),.rst(rst),.clear(clear),
+      .datain(datain), .write(write), .full(full),
+      .dataout(data_int), .read(transfer), .empty(empty_int),
+      .space(s1_space),.occupied(s1_occupied) );
+      
+   longfifo #(.WIDTH(WIDTH),.SIZE(SIZE)) longfifo
+     (.clk(clk),.rst(rst),.clear(clear),
+      .datain(data_int), .write(transfer), .full(full_int),
+      .dataout(data_int2), .read(transfer2), .empty(empty_int2),
+      .space(l_space),.occupied(l_occupied) );
+   
+   shortfifo #(.WIDTH(WIDTH)) shortfifo2
+     (.clk(clk),.rst(rst),.clear(clear),
+      .datain(data_int2), .write(transfer2), .full(full_int2),
+      .dataout(dataout), .read(read), .empty(empty),
+      .space(s2_space),.occupied(s2_occupied) );
+   
+   assign 	    transfer = ~empty_int & ~full_int; 	    
+   assign 	    transfer2 = ~empty_int2 & ~full_int2; 	    
+   
+   assign 	    space = {11'b0,s1_space} + {11'b0,s2_space} + l_space;
+   assign 	    occupied = {11'b0,s1_occupied} + {11'b0,s2_occupied} + l_occupied;
+      
+endmodule // cascadefifo2
+
+
+
+